Name: CUNYFirst ID Number:

Type your name and CUNYFirst ID # above.

Ada Language Subset 1 (ADALS1) Grammar

<S> → procedure IDENT is <DECPART> begin <SEQOFSTMT> end ; EOI

<DECPART> → ε

<DECPART> → <OBJECTDEC> <DECPART>

<OBJECTDEC> → <IDENTLIST> : boolean ;

<OBJECTDEC> → <IDENTLIST> : integer ;

<IDENTLIST> → IDENT

<IDENTLIST> → IDENT , <IDENTLIST>

<SEQOFSTMT> → <STATEMENT>

<SEQOFSTMT> → <STATEMENT> <SEQOFSTMT>

<STATEMENT> → null ;

<STATEMENT> → IDENT := <EXPRESSION> ;

<STATEMENT> → if <CONDITION> then <SEQOFSTMT> end if ;

<STATEMENT> → if <CONDITION> then <SEQOFSTMT>

else <SEQOFSTMT> end if ;

<STATEMENT> → while <CONDITION> loop <SEQOFSTMT> end loop ;

<STATEMENT> → get ( <IDENTLIST> ) ;

<STATEMENT> → put ( <IDENTLIST> ) ;

<STATEMENT> → newline ;

<CONDITION> → <EXPRESSION>

<EXPRESSION> → <SIMPEXPR>

<EXPRESSION> → <SIMPEXPR> = <SIMPEXPR>

<EXPRESSION> → <SIMPEXPR> /= <SIMPEXPR>

<EXPRESSION> → <SIMPEXPR> < <SIMPEXPR>

<EXPRESSION> → <SIMPEXPR> <= <SIMPEXPR>

<EXPRESSION> → <SIMPEXPR> > <SIMPEXPR>

<EXPRESSION> → <SIMPEXPR> >= <SIMPEXPR>

<SIMPEXPR> → <SIMPEXPR> + <TERM>

<SIMPEXPR> → <SIMPEXPR> - <TERM>

<SIMPEXPR> → <TERM>

<TERM> → <TERM> \* <PRIMARY>

<TERM> → <TERM> / <PRIMARY>

<TERM> → <TERM> rem <PRIMARY>

<TERM> → <PRIMARY>

<PRIMARY> → ( <EXPRESSION> )

<PRIMARY> → IDENT

<PRIMARY> → NUMLIT

<PRIMARY> → true

<PRIMARY> → false